Testing the World Extension

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.24;
 
import { MudTest } from "@latticexyz/world/test/MudTest.t.sol";
import { console2 } from "forge-std/Test.sol";
 
import { WorldRegistrationSystem } from "@latticexyz/world/src/modules/init/implementations/WorldRegistrationSystem.sol";
import { System } from "@latticexyz/world/src/System.sol";
 
import { Systems } from "@latticexyz/world/src/codegen/tables/Systems.sol";
 
import { ResourceId } from "@latticexyz/store/src/ResourceId.sol";
import { ResourceIds } from "@latticexyz/store/src/codegen/tables/ResourceIds.sol";
import { WorldResourceIdLib, ROOT_NAMESPACE } from "@latticexyz/world/src/WorldResourceId.sol";
import { RESOURCE_SYSTEM } from "@latticexyz/world/src/worldResourceTypes.sol";
import { StoreSwitch } from "@latticexyz/store/src/StoreSwitch.sol";
 
import { ReadDemoSystem } from "../src/systems/ReadDemoSystem.sol";
 
import { IWorld } from "../src/codegen/world/IWorld.sol";
import { IWorld as IPrimodiumWorld } from "primodium/world/IWorld.sol";
import { ISpawnSystem } from "primodium/world/ISpawnSystem.sol";
 
import { FunctionSelectors } from "@latticexyz/world/src/codegen/tables/FunctionSelectors.sol";
 
contract ReadDemoTest is MudTest {
 
  address extensionDeployerAddress = vm.envAddress("ADDRESS_ALICE");
  address playerAddressActive = vm.envAddress("ADDRESS_PLAYER_ACTIVE");
  address playerAddressInactive = vm.envAddress("ADDRESS_PLAYER_INACTIVE");
 
  bytes14 PRIMODIUM_NAMESPACE = bytes14("Pri_11");
  bytes14 namespace = bytes14("PluginExamples");
  bytes16 system = bytes16("ReadDemoSystem");
 
  function setUp() public override {
    super.setUp();
 
    worldAddress = vm.envAddress("WORLD_ADDRESS");
    StoreSwitch.setStoreAddress(worldAddress);
 
    vm.createSelectFork(vm.envString("PRIMODIUM_RPC_URL"), vm.envUint("BLOCK_NUMBER"));
    console2.log("\nForkLivePrimodium is running.");
 
    WorldRegistrationSystem world = WorldRegistrationSystem(worldAddress);
 
    ResourceId namespaceResource = WorldResourceIdLib.encodeNamespace(bytes14(namespace));
    ResourceId systemResource = WorldResourceIdLib.encode(RESOURCE_SYSTEM, namespace, system);
 
    vm.startPrank(extensionDeployerAddress);
 
    // check if the namespace already exists
    // if you own the namespace, you can change/deregister it via other code
    // if you do not own the namespace but it is already registered, you will need to change your namespace
    bool existingNamespaceCheck = ResourceIds.getExists(namespaceResource);
    assertFalse(existingNamespaceCheck, "Namespace already exists.");
 
    world.registerNamespace(namespaceResource);
 
    ReadDemoSystem readDemoSystem = new ReadDemoSystem();
    world.registerSystem(systemResource, readDemoSystem, true);
 
    world.registerFunctionSelector(systemResource, "readMainBaseLevel()");
 
    vm.stopPrank();
  }
 
  function test_ReadMainBaseLevel_Inactive() public {
    vm.startPrank(playerAddressInactive);
 
    uint32 baseLevel = IWorld(worldAddress).PluginExamples__readMainBaseLevel();
 
    vm.stopPrank();
    assertEq(baseLevel, 0, "The base level should be 0 for an Inactive player.");
  }
 
  function test_ReadMainBaseLevel_Active() public {
    vm.startPrank(playerAddressActive);
 
    uint32 baseLevel = IWorld(worldAddress).PluginExamples__readMainBaseLevel();
 
    vm.stopPrank();
    assertEq(baseLevel, 1, "The base level should be 1 for an Active player.");
  }
 
  function test_SpawnAndReadMainBaseLevel() public {
    vm.startPrank(playerAddressInactive);
 
    uint32 baseLevel = IWorld(worldAddress).PluginExamples__readMainBaseLevel();
 
    IPrimodiumWorld(worldAddress).Pri_11__spawn();
    baseLevel = IWorld(worldAddress).PluginExamples__readMainBaseLevel();
    vm.stopPrank();
    assertEq(baseLevel, 1, "The base level should be 1 for a freshly spawned player.");
  }
}